【ExcelVBA】ActiveXボタンをフォームボタンに置換するマクロ

Excel2024からActiveXコントロールが使用できなくなりました。

ActiveXコントロール

理由が「セキュリティの脆弱性」であるため、
Excel365も追従する可能性が高いです。

新規に挿入することはもちろんできなくなりますが、
既存のコントロールも選択や押下ができなくなり、
そこに設置したマクロ(イベント)も実行できなくなります。

この問題に対応するための、
アクティブシートの全ActiveXボタンを一括でフォームボタンに置き換えるマクロ
を紹介します。

ActiveXから置き換わったフォームボタン
↑こんな感じで、同じ位置/同じ大きさ/同じマクロをセットした、
「元_ボタン名」というフォームボタンを生成します。

実行型の便利マクロですので、
Excel起動時に裏で開かれる「個人用マクロブック」などに搭載して使ってください。

と言いつつこのマクロはある程度作業が終われば不要になるものなので、
普通のブックに書いておき、使い終わったら押し入れにしまうくらいがちょうどいいかもしれません。

ソースコード
解説

ソースコード

Sub アクティブシートのActiveXコントロールボタンをフォームコントロールボタンに置き換える()
    
    Dim 対象シート As Worksheet: Set 対象シート = ActiveSheet
    
    ' ActiveXコントロールのうちCommandButtonだけを処理
    Dim OLEオブジェクト As OLEObject
    For Each OLEオブジェクト In 対象シート.OLEObjects
        If TypeName(OLEオブジェクト.Object) = "CommandButton" Then
        
            ' 位置・サイズ・キャプション(テキスト)・マクロ名を取得
            Dim ボタンtop As Double, ボタンleft As Double
            Dim ボタンwidth As Double, ボタンheight As Double
            Dim ボタンテキスト As String, ボタン名 As String, マクロ名 As String
            With OLEオブジェクト
                ボタンtop = .Top
                ボタンleft = .Left
                ボタンwidth = .Width
                ボタンheight = .Height
                ボタンテキスト = .Object.Caption
                ボタン名 = .Name
                マクロ名 = 対象シート.CodeName & "." & .Name & "_Click"
            End With
            
            ' 同じ位置に同じ大きさでフォームコントロールのボタンを挿入
            Dim フォームボタン As Button
            Set フォームボタン = 対象シート.Buttons.Add( _
                Top:=ボタンtop, Left:=ボタンleft, _
                Width:=ボタンwidth, Height:=ボタンheight)
            
            ' ActiveXボタンの設定を追加したフォームボタンに反映
            With フォームボタン
                .Name = "元_" & ボタン名
                .Caption = ボタンテキスト
                .OnAction = マクロ名
            End With
            
            ' ActiveXボタンを削除
            OLEオブジェクト.Delete
            
        End If
    Next ' ActiveXコントロールのうちCommandButtonだけを処理
    
    MsgBox "すべてのActiveXボタンの置き換えを完了しました。"

End Sub